Added Emboss project

Author: FalsinSoft

QML/Emboss/Emboss.pro

@@ -0,0 +1,9 @@
+QT += quick
+
+CONFIG += c++11
+
+SOURCES += \
+        main.cpp
+
+RESOURCES += qml.qrc
+

QML/Emboss/Emboss.qml

@@ -0,0 +1,39 @@
+
+import QtQuick 2.12
+import QtGraphicalEffects 1.0
+
+Item {
+    id: emboss
+
+    property alias source: topLeftShadow.source
+    property color lightColor: "white"
+    property color darkColor: "black"
+    property bool cached: true
+    property real radius: 1
+    property real spread: 0.1
+    property real offset: 1
+
+    InnerShadow {
+        id: topLeftShadow
+        anchors.fill: parent
+        cached: emboss.cached
+        horizontalOffset: emboss.offset
+        verticalOffset: emboss.offset
+        color: emboss.lightColor
+        radius: emboss.radius
+        samples: emboss.radius * 2
+        spread: emboss.spread
+    }
+    InnerShadow {
+        id: bottomRightShadow
+        anchors.fill: parent
+        cached: emboss.cached
+        source: topLeftShadow
+        horizontalOffset: -emboss.offset
+        verticalOffset: -emboss.offset
+        color: emboss.darkColor
+        radius: emboss.radius
+        samples: emboss.radius * 2
+        spread: emboss.spread
+    }
+}

QML/Emboss/main.cpp

@@ -0,0 +1,20 @@
+#include <QGuiApplication>
+#include <QQmlApplicationEngine>
+
+int main(int argc, char *argv[])
+{
+    QCoreApplication::setAttribute(Qt::AA_EnableHighDpiScaling);
+
+    QGuiApplication app(argc, argv);
+
+    QQmlApplicationEngine engine;
+    const QUrl url(QStringLiteral("qrc:/main.qml"));
+    QObject::connect(&engine, &QQmlApplicationEngine::objectCreated,
+                     &app, [url](QObject *obj, const QUrl &objUrl) {
+        if (!obj && url == objUrl)
+            QCoreApplication::exit(-1);
+    }, Qt::QueuedConnection);
+    engine.load(url);
+
+    return app.exec();
+}

QML/Emboss/main.qml

@@ -0,0 +1,72 @@
+import QtQuick 2.12
+import QtQuick.Window 2.12
+import QtGraphicalEffects 1.12
+
+Window {
+    visible: true
+    width: 480
+    height: 480
+    title: qsTr("Emboss")
+    color: "lightsteelblue"
+
+    Grid {
+        anchors.centerIn: parent
+        columns: 2
+        spacing: 10
+
+        Rectangle {
+            width: 200
+            height: 200
+            radius: 10
+            gradient: "LandingAircraft"
+
+            Emboss {
+                anchors.fill: parent
+                source: parent
+                offset: 2
+                radius: 3
+            }
+        }
+        Rectangle {
+            width: 200
+            height: 200
+            radius: 10
+            gradient: "LandingAircraft"
+
+            Emboss {
+                anchors.fill: parent
+                source: parent
+                offset: -2
+                radius: 3
+            }
+        }
+        Rectangle {
+            width: 200
+            height: 200
+            radius: 10
+            gradient: "AboveTheSky"
+
+            Emboss {
+                anchors.fill: parent
+                source: parent
+                opacity: 0.6
+                offset: 2
+                radius: 6
+            }
+        }
+        Rectangle {
+            width: 200
+            height: 200
+            radius: 10
+            gradient: "AboveTheSky"
+
+            Emboss {
+                anchors.fill: parent
+                source: parent
+                opacity: 0.6
+                offset: -2
+                radius: 6
+            }
+        }
+    }
+}

QML/Emboss/qml.qrc

@@ -0,0 +1,6 @@
+<RCC>
+    <qresource prefix="/">
+        <file>main.qml</file>
+        <file>Emboss.qml</file>
+    </qresource>
+</RCC>