Merge pull request #8 from chirp/feature/nano33sense_rx_example

Add receive example for Nano 33 Sense

Author: Damien Laidin

examples/Nano33SenseReceive/Nano33SenseReceive.ino

@@ -0,0 +1,148 @@
+/**-----------------------------------------------------------------------------
+
+    Example code to receive data using Arduino Nano 33 Sense board.
+
+    @file Nano33SenseReceive.ino
+
+    @brief Create a developer account at https://developers.chirp.io,
+    and copy and paste your key, secret and config string for the "arduino"
+    protocol into the credentials.h file.
+
+    This example will start listening for chirps and print to the terminal
+    when anything is received.
+
+    Note: this example can be used in conjunction with the send example,
+    to send and receive data in the same application.
+
+    Circuit:
+      - Arduino Nano 33 BLE board
+
+    Copyright © 2011-2019, Asio Ltd.
+    All rights reserved.
+
+  ----------------------------------------------------------------------------*/
+#include <PDM.h>
+
+#include "chirp_connect.h"
+#include "credentials.h"
+
+#define SAMPLE_RATE       16000
+#define BUFFER_SIZE       256
+
+// Global variables ------------------------------------------------------------
+
+static chirp_connect_t *chirp = NULL;
+short sampleBuffer[BUFFER_SIZE];
+uint32_t counter;
+volatile int samplesRead;
+
+// Function definitions --------------------------------------------------------
+
+void setupChirp(void);
+void chirpErrorHandler(chirp_connect_error_code_t code);
+void onPDMdata(void);
+
+// Main ------------------------------------------------------------------------
+
+void setup()
+{
+  Serial.begin(115200);
+  while (!Serial);
+
+  setupChirp();
+
+  PDM.onReceive(onPDMdata);
+  PDM.setGain(30);
+
+  if (!PDM.begin(1, SAMPLE_RATE))
+  {
+    Serial.println("Failed to start PDM!");
+    while (1);
+  }
+}
+
+void loop()
+{
+  if (samplesRead)
+  {
+    chirp_connect_error_code_t err = chirp_connect_process_shorts_input(chirp, sampleBuffer, samplesRead);
+    chirpErrorHandler(err);
+    samplesRead = 0;
+  }
+}
+
+void onPDMdata()
+{
+  int bytesAvailable = PDM.available();
+  PDM.read(sampleBuffer, bytesAvailable);
+  samplesRead = bytesAvailable / sizeof(short);
+}
+
+// Chirp -----------------------------------------------------------------------
+
+void onReceivingCallback(void *chirp, uint8_t *payload, size_t length, uint8_t channel)
+{
+  Serial.println("Receiving data...");
+}
+
+void onReceivedCallback(void *chirp, uint8_t *payload, size_t length, uint8_t channel)
+{
+  if (payload)
+  {
+    char *data = (char *)calloc(length + 1, sizeof(uint8_t));
+    memcpy(data, payload, length * sizeof(uint8_t));
+    Serial.print("Received data: ");
+    Serial.println(data);
+    free(data);
+  }
+  else
+  {
+    Serial.println("Decode failed.");
+  }
+}
+
+void chirpErrorHandler(chirp_connect_error_code_t code)
+{
+  if (code != CHIRP_CONNECT_OK)
+  {
+    const char *error_string = chirp_connect_error_code_to_string(code);
+    Serial.println(error_string);
+    exit(42);
+  }
+}
+
+void setupChirp(void)
+{
+  chirp = new_chirp_connect(CHIRP_APP_KEY, CHIRP_APP_SECRET);
+  if (chirp == NULL)
+  {
+    Serial.println("Chirp initialisation failed.");
+    return;
+  }
+
+  chirp_connect_error_code_t err = chirp_connect_set_config(chirp, CHIRP_APP_CONFIG);
+  chirpErrorHandler(err);
+
+  chirp_connect_callback_set_t callback_set = {
+    .on_state_changed = NULL,
+    .on_sending = NULL,
+    .on_sent = NULL,
+    .on_receiving = onReceivingCallback,
+    .on_received = onReceivedCallback
+  };
+
+  err = chirp_connect_set_callbacks(chirp, callback_set);
+  chirpErrorHandler(err);
+
+  err = chirp_connect_set_input_sample_rate(chirp, SAMPLE_RATE);
+  chirpErrorHandler(err);
+
+  err = chirp_connect_set_frequency_correction(chirp, 1.0096);
+  chirpErrorHandler(err);
+
+  err = chirp_connect_start(chirp);
+  chirpErrorHandler(err);
+
+  Serial.println("Chirp SDK initialised.");
+  Serial.flush();
+}

examples/Nano33SenseReceive/credentials.h

@@ -0,0 +1,21 @@
+/*------------------------------------------------------------------------------
+ *
+ *  Credentials.h
+ *
+ *  For full information on usage and licensing, see https://chirp.io/
+ *
+ *  Copyright © 2011-2019, Asio Ltd.
+ *  All rights reserved.
+ *
+ *----------------------------------------------------------------------------*/
+
+#ifndef Credentials_h
+#define Credentials_h
+
+#error("Add your credentials below (from https://developers.chirp.io) and delete this line.")
+
+#define CHIRP_APP_KEY        "YOUR_APP_KEY"
+#define CHIRP_APP_SECRET     "YOUR_APP_SECRET"
+#define CHIRP_APP_CONFIG     "YOUR_APP_CONFIG"
+
+#endif /* Credentials_h */